Accessの名簿データをExcelへ 1208修正・追加１．年齢の表示、Excelへの出力(代入)

1208修正・追加１．年齢の表示、Excelへの出力(代入)

>年齢はどういう風に表示したらよろしいでしょうか？フォーム上では
>
>=IIf(Format([生年月日],"mm/dd")>Format(Date(),"mm/dd"),DateDiff("yyyy",[生年月日],Date())-1,DateDiff("yyyy",[生年月日],Date())) & "才"
>
>で出してます、それをコピーして貼り付けたら赤く表示された。

年齢は、
フォーム上(F社員入力)では
>=IIf(Format([生年月日],"mm/dd")>Format(Date(),"mm/dd"),DateDiff("yyyy",[生年月日],Date())-1,DateDiff("yyyy",[生年月日],Date())) & "才"
で、できるなら、

ポイントがフォームだと
[生年月日]
↑これを、レコードセットrsなので、

セル = IIf(Format(rs.Fields("生年月日"),"mm/dd")>Format(Date(),"mm/dd"),DateDiff("yyyy",rs.Fields("生年月日"),Date())-1,DateDiff("yyyy",rs.Fields("生年月日"),Date())) & "才"
とrs.Fields("生年月日")に置き換えるとか？

長くなるので、
Dim yyyymmdd as date
yyyymmdd = rs.Fields("生年月日")
=IIf(Format(yyyymmdd,"mm/dd")>Format(Date(),"mm/dd"),DateDiff("yyyy",yyyymmdd,Date())-1,DateDiff("yyyy",yyyymmdd,Date())) & "才"
と変数に一回入れて、その後 IIfでもいいのかなぁ？

下記のような感じで、作成してみました。

Private Sub コマンド10_Click()

    Dim oApp As Object     'Excelアプリの参照用
    Dim strWORK As String  '文字編集用のワーク変数
    Dim i As Integer
    Dim strMDBPATH As String   'MDBの保存場所、フォルダー・ディレクトリ
    Dim strXLSFILE As String   'テンプレートファイルの名前、e:\xxx\yyyy\テンプレート.xls

    Dim rs As New ADODB.Recordset  'ADOのレコードセットです。
    Dim y As Integer  'セットする行番号です

    Me.Refresh  '.Refreshでフォームを更新する(フラグ更新)を強制的に(明示的に)行う

  '印刷FLGがYesのデータを集める。
    rs.Open "select * from 社員テーブル where 印刷FLG=Yes", CurrentProject.Connection, _
                                adOpenKeyset, adLockOptimistic
                                
    If rs.RecordCount = 0 Then '選択件数のチェック
        MsgBox "転送データが選択されていません。"
        Exit Sub  '↑メッセージを表示して関数を抜ける
    End If

  'Excelファイルを開く
    'Accessの起動位置を取得 CurrentDb.NameにD:\xxxx\yyyy\zzz.mdbが入っている
    strWORK = CurrentDb.Name
    
    '後ろから１文字単位で￥を探す
    For i = Len(strWORK) To 1 Step -1
        If Mid(strWORK, i, 1) = "\" Then Exit For  '￥だったら抜ける
    Next i
    
    'D:\xxxx\yyyy\zzz.mdb --> D:\xxxx\yyyy\ にする
    strMDBPATH = Mid(strWORK, 1, i)

    'Excelの元ファイルの名前を作成　D:\xxxx\yyyy\ ＋ テンプレート.xls
    strXLSFILE = strMDBPATH & "テンプレート.xls"
    
    'ファイルの存在をチェックする
    If Dir(strXLSFILE) = "" Then
        MsgBox strXLSFILE & " の存在を 確認して下さい"
        Exit Sub  'エラーなので途中で抜ける
    End If

    Set oApp = CreateObject("Excel.Application")
    oApp.Visible = True
    'Only XL 97 supports UserControl Property
    On Error Resume Next
    oApp.UserControl = True

    'テンプレートファイルを開く
    oApp.Workbooks.Open Filename:=strXLSFILE
    
    'テンプレートファイルをcopy 2009-11-28 追加
    oApp.Windows("テンプレート.xls").Activate
    oApp.Sheets("名簿").Select
    oApp.Sheets("名簿").Copy
    oApp.Windows("テンプレート.xls").Activate
    oApp.ActiveWorkbook.Close
                                
  'AccessのデータをExcelへ代入する。
    'ループ処理
    y = 4  '4行目からセットします。
    Dim yyyymmdd As Date   '生年月日を一時的に入れておく変数

    While rs.EOF = False  'いつものEOFが偽の間
        
        oApp.cells(y, "A") = rs.Fields("社員番号") 'データをExcelへセットする。
        
        oApp.cells(y, "B") = rs.Fields("氏名")
        oApp.cells(y + 1, "B") = rs.Fields("ふりがな") '※２段目なのでy+1
        
        yyyymmdd = rs.Fields("生年月日")  '変数に代入してから↓で計算してみる
        oApp.cells(y, "C") = IIf(Format(yyyymmdd, "mm/dd") > Format(Date, "mm/dd"), DateDiff("yyyy", yyyymmdd, Date) - 1, DateDiff("yyyy", yyyymmdd, Date)) & "才"
        
        oApp.cells(y + 1, "C") = rs.Fields("性別")
        
        oApp.cells(y, "D") = rs.Fields("郵便番号") & " " & rs.Fields("住所")
        
        oApp.cells(y, "E") = rs.Fields("電話番号")
        oApp.cells(y + 1, "E") = rs.Fields("本籍")
        
        oApp.cells(y, "F") = rs.Fields("配偶者有無")

        oApp.cells(y, "G") = rs.Fields("雇用年月日")
      
        'H列に持っている資格複数をセットする。
        oApp.cells(y, "H") = get資格(rs.Fields("社員番号"))
         
        rs.MoveNext  '次のレコードに移動しないと、とんでもないことに(笑)
        y = y + 2    '1つの名簿データで2行使うので、＋２で次の行です
    Wend

    rs.Close   '開いたら閉じろ、ドアを開けたら閉めるってしつけられたでしょ(笑)
    Set rs = Nothing  '変数も後始末しますか。使った器はキレイにしろって?

  '書式の調整
    Const xlPasteFormats = &HFFFFEFE6  '参照設定していないので、
    Const xlNone = &HFFFFEFD2          '定数固定値として同じ名前で定義
    'データの終わり、y-1まで、書式(罫線など)をコピーする
    oApp.Rows("4:5").Copy   '基準となる１件目をコピーする(4行目・5行目)
    oApp.Rows("6:" & y - 1).Select  'データの範囲を6行目から選択
    oApp.Range("B6").Activate
    '書式だけを貼り付ける。(Paste:=xlPasteFormatsを指定する)
    oApp.Selection.PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, _
        SkipBlanks:=False, Transpose:=False
    oApp.Application.CutCopyMode = False
    oApp.Range("A4").Select  '書式のコピー終了後、カーソルを先頭へ・・・

End Sub

修正場所は変数定義(Dim yyyymmdd As Date)を入れても３行かなぁ。

yyyymmdd = rs.Fields("生年月日") '変数に代入してから↓で計算してみる
oApp.cells(y, "C") = IIf(Format(yyyymmdd, "mm/dd") > Format(Date, "mm/dd"), DateDiff("yyyy", yyyymmdd, Date) - 1, DateDiff("yyyy", yyyymmdd, Date)) & "才"

※コントロールソースだと、ムリしてIIfを使って1行に書かないとダメですが、

yyyymmdd = rs.Fields("生年月日")
If(Format(yyyymmdd, "mm/dd") > Format(Date, "mm/dd") Then
    str年齢 = DateDiff("yyyy", yyyymmdd, Date) - 1
Else
    str年齢 = DateDiff("yyyy", yyyymmdd, Date)) & "才"
End If
oApp.cells(y, "C") = str年齢  '↑上で計算した年齢を代入