Accessの名簿データをExcelへ 1208修正・追加２．同じような３つのマスター項目を管理したい

1208修正・追加２．同じような３つのマスター項目を管理したい

世の中には、会社の数分だけ社員名簿がある、じゃなくって、
イロイロとカスタマイズ？に挑戦してみます。

>資格は免許とかその他や技能と別れてまして、
>テーブルの資格もわけないといけないでしょうか？

資格教育テーブル
資格資格テーブル
資格免許テーブル

と分けると、面倒なので、

免許とか教育は
は
資格テーブルに教育,資格,免許,を1,2,3とかA,B,Cとか、区分を入力しておいて、

strSQL = "select * from Q資格"
strSQL = strSQL & " where 社員番号='" & 社員番号 & "'"
strSQL = strSQL & " And 区分='C'" 'Cの区分のみ
など、で切り替えて引っぱってくるのがいいのかなぁ。
※テーブルを新たに作ると大変なので、

資格名称テーブルに区分を追加して、

A教育,B資格,C免許

資格ID 名称 ..... 区分
1 普通免許 C
2 シスアド B
3 PC操作講習 A

にして、
社員番号と区分を渡して、３回取ってくるとか？

oApp.cells(y, "列") = get資格(rs.Fields("社員番号"),"A") '教育
oApp.cells(y, "列") = get資格(rs.Fields("社員番号"),"B") '資格
oApp.cells(y, "列") = get資格(rs.Fields("社員番号"),"C") '免許

※すでに分類があったので、使っていない分類を使用します(ぉぃぉぃ)

またまた、修正箇所が少ないですが、下記のような感じで修正しました。
※忘れずにデータ転記先のテンプレート.xls も教育,資格,免許の3つワクを作ります。

Option Compare Database
Option Explicit

Private Sub コマンド10_Click()

    Dim oApp As Object     'Excelアプリの参照用
    Dim strWORK As String  '文字編集用のワーク変数
    Dim i As Integer
    Dim strMDBPATH As String   'MDBの保存場所、フォルダー・ディレクトリ
    Dim strXLSFILE As String   'テンプレートファイルの名前、e:\xxx\yyyy\テンプレート.xls

    Dim rs As New ADODB.Recordset  'ADOのレコードセットです。
    Dim y As Integer  'セットする行番号です

    Me.Refresh  '.Refreshでフォームを更新する(フラグ更新)を強制的に(明示的に)行う

  '印刷FLGがYesのデータを集める。
    rs.Open "select * from 社員テーブル where 印刷FLG=Yes", CurrentProject.Connection, _
                                adOpenKeyset, adLockOptimistic
                                
    If rs.RecordCount = 0 Then '選択件数のチェック
        MsgBox "転送データが選択されていません。"
        Exit Sub  '↑メッセージを表示して関数を抜ける
    End If

  'Excelファイルを開く
    'Accessの起動位置を取得 CurrentDb.NameにD:\xxxx\yyyy\zzz.mdbが入っている
    strWORK = CurrentDb.Name
    
    '後ろから１文字単位で￥を探す
    For i = Len(strWORK) To 1 Step -1
        If Mid(strWORK, i, 1) = "\" Then Exit For  '￥だったら抜ける
    Next i
    
    'D:\xxxx\yyyy\zzz.mdb --> D:\xxxx\yyyy\ にする
    strMDBPATH = Mid(strWORK, 1, i)

    'Excelの元ファイルの名前を作成　D:\xxxx\yyyy\ ＋ テンプレート.xls
    strXLSFILE = strMDBPATH & "テンプレート.xls"
    
    'ファイルの存在をチェックする
    If Dir(strXLSFILE) = "" Then
        MsgBox strXLSFILE & " の存在を 確認して下さい"
        Exit Sub  'エラーなので途中で抜ける
    End If

    Set oApp = CreateObject("Excel.Application")
    oApp.Visible = True
    'Only XL 97 supports UserControl Property
    On Error Resume Next
    oApp.UserControl = True

    'テンプレートファイルを開く
    oApp.Workbooks.Open Filename:=strXLSFILE
    
    'テンプレートファイルをcopy 2009-11-28 追加
    oApp.Windows("テンプレート.xls").Activate
    oApp.Sheets("名簿").Select
    oApp.Sheets("名簿").Copy
    oApp.Windows("テンプレート.xls").Activate
    oApp.ActiveWorkbook.Close
                                
  'AccessのデータをExcelへ代入する。
    'ループ処理
    y = 4  '4行目からセットします。
    Dim yyyymmdd As Date   '生年月日を一時的に入れておく変数

    While rs.EOF = False  'いつものEOFが偽の間
        
        oApp.cells(y, "A") = rs.Fields("社員番号") 'データをExcelへセットする。
        
        oApp.cells(y, "B") = rs.Fields("氏名")
        oApp.cells(y + 1, "B") = rs.Fields("ふりがな") '※２段目なのでy+1
        
        yyyymmdd = rs.Fields("生年月日")  '変数に代入してから↓で計算してみる
        oApp.cells(y, "C") = IIf(Format(yyyymmdd, "mm/dd") > Format(Date, "mm/dd"), DateDiff("yyyy", yyyymmdd, Date) - 1, DateDiff("yyyy", yyyymmdd, Date)) & "才"
        
        oApp.cells(y + 1, "C") = rs.Fields("性別")
        
        oApp.cells(y, "D") = rs.Fields("郵便番号") & " " & rs.Fields("住所")
        
        oApp.cells(y, "E") = rs.Fields("電話番号")
        oApp.cells(y + 1, "E") = rs.Fields("本籍")
        
        oApp.cells(y, "F") = rs.Fields("配偶者有無")

        oApp.cells(y, "G") = rs.Fields("雇用年月日")
      
        'H列に持っている資格複数をセットする。
        oApp.cells(y, "H") = get資格(rs.Fields("社員番号"), "A")
        oApp.cells(y, "I") = get資格(rs.Fields("社員番号"), "B")
        oApp.cells(y, "J") = get資格(rs.Fields("社員番号"), "C")

        rs.MoveNext  '次のレコードに移動しないと、とんでもないことに(笑)
        y = y + 2    '1つの名簿データで2行使うので、＋２で次の行です
    Wend

    rs.Close   '開いたら閉じろ、ドアを開けたら閉めるってしつけられたでしょ(笑)
    Set rs = Nothing  '変数も後始末しますか。使った器はキレイにしろって?

  '書式の調整
    Const xlPasteFormats = &HFFFFEFE6  '参照設定していないので、
    Const xlNone = &HFFFFEFD2          '定数固定値として同じ名前で定義
    'データの終わり、y-1まで、書式(罫線など)をコピーする
    oApp.Rows("4:5").Copy   '基準となる１件目をコピーする(4行目・5行目)
    oApp.Rows("6:" & y - 1).Select  'データの範囲を6行目から選択
    oApp.Range("B6").Activate
    '書式だけを貼り付ける。(Paste:=xlPasteFormatsを指定する)
    oApp.Selection.PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, _
        SkipBlanks:=False, Transpose:=False
    oApp.Application.CutCopyMode = False
    oApp.Range("A4").Select  '書式のコピー終了後、カーソルを先頭へ・・・

End Sub

'社員番号を受け取り、持っている資格名称を返すサブ関数
Private Function get資格(社員番号 As String, 分類 As String) As String

    Dim strSQL As String
    
    strSQL = "select * from Q資格"
    strSQL = strSQL & " where 社員番号='" & 社員番号 & "'"
    strSQL = strSQL & " And 分類='" & 分類 & "'"  '分類を指定
    
    Dim strRET As String
    Dim rs As New ADODB.Recordset
    rs.Open strSQL, CurrentProject.Connection, _
                                adOpenKeyset, adLockOptimistic
    'ループ処理
    strRET = ""  'リターン値の初期化
    
    If rs.RecordCount > 0 Then '資格が1つでもあったら(0件以上)
        While rs.EOF = False  'いつものEOFが偽の間
            strRET = strRET & rs.Fields("資格名称") & " "
            rs.MoveNext  '次のレコードに移動しないと、とんでもないことに(笑)
        Wend
    End If

    rs.Close   '開いたら閉じろ、ドアを開けたら閉めるってしつけられたでしょ(笑)
    Set rs = Nothing  '変数も後始末しますか。使った器はキレイにしろって?

    get資格 = strRET  '作成した変数を返す

End Function